Why does this loop execute only once for j=1.Can anyone tell what is wrong?

let i(integer)
let tempcurve(curve)

let j(integer)
let k(integer)
i = 1
j=1
k=1
k=NODTemp

Message("temp=",NODFinal )

for j while j<=NODFinal 
 
{  
 Message("j=",j)
 for i while i <= DissCurves .Size()
  
 {  
  If k ==1    
  {tempcurve = DissCurves .GetItem(i)
    
  }
  else
  {tempcurve = assemble(tempcurve, DissCurves.GetItem(i))    
  }   
  New_Curves->SetAttributeObject("Curve."+j ,tempcurve)
       
  Message("i=",i)
  
 }
}

I'm not sure to understand completely the way you want it to work.

I don't understand where the number of curves by domain is deduced : you have to know it if you want your rule to work because you have to assemble those curves only (the assemble method allows to assemble non connected domains)

Few remarks:
- it would be easier to use assemble(list)
- I have the feeling that there is a problem around k management: in case of NODTemp <> 1, you never go in tempcurve initialization and assemble an empty curve with other curves (don't know the result).

You did not say what is DissCurves. I assume it is a list with all disassembled curves.

In this case, I think that with NODTemp = 1, the result is the same for all resulting curves : they assemble all disassembled curves with your algorithm

If the disassembled curves are sorted (curves belonging to a given domain are consecutive), I would do it something like that:

let onedomaincurves (List)
let domainindex (List)
let c (Curve)
let i (integer)
let j (integer)
let k (integer)
beginning = 1
i = 1

for i while i <= nbDomains
{
j = beginning
for j while j <= nbCurves - 1
{
c = assemble(curves->GetItem(i), curves.GetItem(i + 1)
if nbDomains(c) > 1
{
domainindex.Append(i + 1) /* domainindex will contain indexes where a new domain begins */
beginning = i + 1
j = nbCurves /* goes out the loop */
}
}
}

/* domainindex.Size() should be equal to nbDomains */

i = 1
k = 1
for i while i <= nbDomains
{
if i == 1
j = 1
else
j = domainindex.GetItem(i) - 1
for j while j < nbCurves
{
if j < domainindex.GetItem(i)
onedomaincurves->Append(curves->GetItem(j)
}

New_Curves->SetAttributeObject("Curve."+i ,assemble(onedomaincurves))
}

Hello knowledgeds,

Thanks for your efforts.I changed your given code but still couldn't succed.

I am attaching the catpart .

Could you give me the solution.

Hello,

there was some errors in my script (i in place of j, RemoveAll missing, and separators go from 1 to nbDomains - 1 and not to nbDomains). Here is the good one


let onedomaincurves (List)
let domainindex (List)
let c (Curve)
let i (integer)
let j (integer)
let k (integer)
let beginning(integer)
let nbDomains(integer)
let nbCurves (integer)
let x(integer)
let m(integer)

i = 1
beginning = 1
nbCurves =DissCurves.Size()

nbDomains=NODSketch


for i while i <= nbDomains - 1
{
    j = beginning
    for j while j <= nbCurves -1
    {   
        c = assemble(DissCurves  ->GetItem(j), DissCurves .GetItem(j +1))
       
        if nbDomains(c) > 1
        {
            domainindex.Append(j + 1) /* domainindex will contain indexes where a new domain begins */
           
            beginning = j + 1
            j = nbCurves
        }
    }
}

domainindex.Append(nbCurves + 1)


i= 1
k = 1
for i while i <= nbDomains
{
    if i == 1
        j = 1
    else
        j = domainindex.GetItem(i - 1) - 1
    for j while j < nbCurves
    {
        if j < domainindex.GetItem(i)
            onedomaincurves->Append(DissCurves->GetItem(j))
    }
   
    Assembled_Curves ->SetAttributeObject("AsmCurve."+i ,assemble(onedomaincurves))
    onedomaincurves.RemoveAll()
}

I modified the script and its now working  as per my expectations.

Thanks a lot Knowledgeds.

/*Rule created by agawalv 1/22/2010*/

let onedomaincurves (List)
let domainindex (List)
let c (Curve)
let i (integer)
let j (integer)
let k (integer)
let beginning(integer)
let nbDomains(integer)
let nbCurves (integer)

i = 1
beginning = 1
nbCurves =DissCurves.Size()

nbDomains=NODSketch

for i while i <= nbDomains
{
 j = beginning
 for j while j <= nbCurves -1
 {   
  c = assemble(DissCurves  ->GetItem(j), DissCurves .GetItem(j +1))
  
  if nbDomains(c) > 1
  {
   domainindex.Append(j + 1) /* domainindex will contain indexes where a new domain begins */
   
   beginning = j + 1
   j = nbCurves
   
  }
 }
}

domainindex.Append(nbCurves  + 1)

i= 1
k = 1

for i while i <= nbDomains
{
 if i == 1
  j = 1
 else
  j = domainindex.GetItem(i- 1 )
 
 
   for j while j <= nbCurves
 {
  if j < domainindex.GetItem(i)
   onedomaincurves->Append(DissCurves ->GetItem(j))
 }
 
 Assembled_Curves   ->SetAttributeObject("AsmCurve."+i ,assemble(onedomaincurves))
 Assembled_Curves.Update()
 onedomaincurves.RemoveAll()
}

Its working.

Thanks a lot knowledgeds.